@Echo Off
Pushd %~dp0
Title QQ2011JayXon绿色精简版辅助工具
If "%PROCESSOR_ARCHITECTURE%"=="AMD64" (Set b=%SystemRoot%\SysWOW64) Else (Set b=%SystemRoot%\system32)
Rd "%b%\test_permissions_JayXon" >nul 2>nul
Md "%b%\test_permissions_JayXon" 2>nul||(Echo 请使用右键管理员身份运行&&Pause >nul&&Exit)
Rd "%b%\test_permissions_JayXon" >nul 2>nul
SetLocal EnableDelayedExpansion
:Menu
Cls
If Exist "%b%\Tasklist.exe" Tasklist|Find /i "qq.exe">nul&&(Echo 请先退出QQ，按任意键重试&&Pause >nul&&Goto Menu)
If Not "%1"=="" (Set c=%1&Goto Goto)
Echo 注：此QQ可以解压直接运行，以下只是一些增强功能
Echo 1.屏蔽扫描硬盘
Echo 2.屏蔽群动态群热点广告(非Hosts)
Echo 3.屏蔽登录面板广告与动态推荐皮肤
Echo 4.修复网络硬盘上传和微博图片上传功能
Echo 5.修复登录超时（慎用）
Echo 6.创建桌面快捷方式
Echo 7.卸载
Echo 8.退出
Set /p c=请输入数字并按Enter确定：
:Goto
If Not "%c%"=="" Set c=%c:~0,1%
If "%c%"=="1" Goto Fuck
If "%c%"=="2" Goto GroupAd
If "%c%"=="3" Goto CSC
If "%c%"=="4" Goto Upload
If "%c%"=="5" Goto Overtime
If "%c%"=="6" Goto lnk
If "%c%"=="7" Goto Uninstall
If "%c%"=="8" Exit
Goto Menu
:Fuck
Rd /s /q "%TMP%\qqsafeud.exe" >nul 2>nul||Del /f /q "%TMP%\qqsafeud.exe" >nul 2>nul
Rd /s /q "%AppData%\Tencent\QQ\SafeBase" >nul 2>nul
Md "%AppData%\Tencent\QQ" >nul 2>nul
Echo.>"%AppData%\Tencent\QQ\SafeBase"
Md "%TMP%\qqsafeud.exe"
Set e=屏蔽完成
Goto MsgBox
:CSC
Rd /s /q "%AppData%\Tencent\QQ\Misc\OAPanelLogo" >nul 2>nul
Rd /s /q "%AppData%\Tencent\QQ\Misc\LogoFile" >nul 2>nul
Rd /s /q "%AppData%\Tencent\QQ\Misc\CSC" >nul 2>nul
Rd /s /q "%AppData%\Tencent\QQ\Skins\RecommendPreview" >nul 2>nul
Md "%AppData%\Tencent\QQ\Misc\CSC\2052" >nul 2>nul
Md "%AppData%\Tencent\QQ\Skins" >nul 2>nul
Echo.>"%AppData%\Tencent\QQ\Misc\OAPanelLogo"
Echo.>"%AppData%\Tencent\QQ\Misc\LogoFile"
Echo.>"%AppData%\Tencent\QQ\Misc\CSC\2052\7"
Echo.>"%AppData%\Tencent\QQ\Skins\RecommendPreview"
Set e=屏蔽完成
Goto MsgBox
:GroupAd
Rd /s /q "%AppData%\Tencent\QQ\Temp\gm" >nul 2>nul
Rd /s /q "%AppData%\Tencent\QQ\Misc\GMF" >nul 2>nul
Md "%AppData%\Tencent\QQ\Misc" >nul 2>nul
Echo.>"%AppData%\Tencent\QQ\Misc\GMF"
Set e=屏蔽完成
Goto MsgBox
:Overtime
Rd /s /q "%CommonProgramFiles%\Tencent" >nul 2>nul
If Exist "%CommonProgramFiles(x86)%" Rd /s /q "%CommonProgramFiles(x86)%\Tencent" >nul 2>nul
:Upload
If "%c%"=="4" Regsvr32 /s Bin\TXFTNActiveX1.17.dll
Set e=修复完成
Goto MsgBox
:Uninstall
Regsvr32 /s /u Bin\TXFTNActiveX1.17.dll
Regsvr32 /s /u Bin\TXSSO\Bin\SSOCommon.dll
If Exist Bin\TXPFProxy.dll Regsvr32 /s /u Bin\TXPFProxy.dll
If Exist Bin\TXSSO\Bin\npSSOAxCtrlForPTLogin.dll Regsvr32 /s /u Bin\TXSSO\Bin\npSSOAxCtrlForPTLogin.dll
If Exist Bin\Timwp.dll Regsvr32 /s /u Bin\Timwp.dll
For /f "skip=2 tokens=1,2 delims=:" %%i in ('Reg Query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /v Desktop') Do (Set d=%%i
Set d=!d:~-1!:%%j\)
Set d=%d:"=%
Del /f /q "%d:\\=\%QQ2011.lnk" >nul 2>nul
Reg Delete "HKLM\SOFTWARE\Tencent\QQ2009" /f >nul 2>nul
Reg Delete "HKCU\SOFTWARE\Tencent\QQ2009" /f >nul 2>nul
Reg Delete "HKLM\SOFTWARE\Wow6432Node\Tencent\QQ2009" /f >nul 2>nul
Rd /s /q "%AppData%\Tencent\QQ" >nul 2>nul
Rd /s /q "%AppData%\Tencent\Logs" >nul 2>nul
Rd /s /q "%TMP%\qqsafeud.exe" >nul 2>nul||Del /f /q "%TMP%\qqsafeud.exe" >nul 2>nul
Rd /s /q "%AllUsersProfile%\Documents\Tencent" >nul 2>nul
Rd /s /q "%AllUsersProfile%\Tencent" >nul 2>nul
Del /f /q "%TMP%\ts*.dat" >nul 2>nul
Del /f /q "%TMP%\t*.tsd" >nul 2>nul
Del /f /q "%TMP%\tvl*.tvl" >nul 2>nul
Set e=卸载完成
Goto MsgBox
:lnk
mshta VBScript:Execute("Set a=CreateObject(""WScript.Shell""):Set b=a.CreateShortcut(a.SpecialFolders(""Desktop"") & ""\QQ2011.lnk""):b.TargetPath=""%~dp0Bin\QQ.exe"":b.WorkingDirectory=""%~dp0Bin\"":b.Save:close")
Set e=创建快捷方式完成
:MsgBox
If "%1"=="" mshta VBScript:Msgbox("%e%",vbSystemModal,"")(close)
Shift /1
Goto Menu