Microsoft® Visual Basic® Scripting Edition 使用循环语句 | VBScript 教程 上一页 | 下一页

##### 使用循环重复执行代码

> 循环用于重复执行一组语句。循环可分为三类：一类在条件变为 False 之前重复执行语句，一类在条件变为 True 之前重复执行语句，另一类按照指定的次数重复执行语句。

> 在 VBScript 中可使用下列循环语句：

> - Do...Loop： 当（或直到）条件为 True 时循环。
> - While...Wend： 当条件为 True 时循环。
> - For...Next： 指定循环次数，使用计数器重复运行语句。
> - For Each...Next： 对于集合中的每项或数组中的每个元素，重复执行一组语句。

##### 使用 Do 循环

> 可以使用 Do...Loop 语句多次（次数不定）运行语句块。当条件为 True 时或条件变为 True 之前，重复执行语句块。

> ##### 当条件为 True 时重复执行语句

> While 关键字用于检查 Do...Loop 语句中的条件。有两种方式检查条件：在进入循环之前检查条件（如下面的 ChkFirstWhile 示例）；或者在循环至少运行完一次之后检查条件（如下面的 ChkLastWhile 示例）。在 ChkFirstWhile 过程中，如果 myNum 的初始值被设置为 9 而不是 20，则永远不会执行循环体中的语句。在 ChkLastWhile 过程中，循环体中的语句只会执行一次，因为条件在检查时已经为 False。

> >      Sub ChkFirstWhile()
> >          Dim counter, myNum
> >          counter = 0
> >          myNum = 20
> >          Do While myNum > 10
> >              myNum = myNum - 1
> >              counter = counter + 1
> >          Loop
> >          MsgBox "循环重复了 " & counter & " 次。"
> >      End Sub

> >      Sub ChkLastWhile()
> >          Dim counter, myNum
> >          counter = 0
> >          myNum = 9
> >          Do
> >              myNum = myNum - 1
> >              counter = counter + 1
> >          Loop While myNum > 10
> >          MsgBox "循环重复了 " & counter & " 次。"
> >      End Sub

> ##### 重复执行语句直到条件变为 True

> Until 关键字用于检查 Do...Loop 语句中的条件。有两种方式检查条件：在进入循环之前检查条件（如下面的 ChkFirstUntil 示例）；或者在循环至少运行完一次之后检查条件（如下面的 ChkLastUntil 示例）。只要条件为 False，就会进行循环。

> >      Sub ChkFirstUntil()
> >          Dim counter, myNum
> >          counter = 0
> >          myNum = 20
> >          Do Until myNum = 10
> >              myNum = myNum - 1
> >              counter = counter + 1
> >          Loop
> >          MsgBox "循环重复了 " & counter & " 次。"
> >      End Sub

> >      Sub ChkLastUntil()
> >          Dim counter, myNum
> >          counter = 0
> >          myNum = 1
> >          Do
> >              myNum = myNum + 1
> >              counter = counter + 1
> >          Loop Until myNum = 10
> >          MsgBox "循环重复了 " & counter & " 次。"
> >      End Sub

> ##### 退出循环

> Exit Do 语句用于退出 Do...Loop 循环。因为通常只是在某些特殊情况下要退出循环（例如要避免死循环），所以可在 If...Then...Else 语句的 True 语句块中使用 Exit Do 语句。如果条件为 False，循环将照常运行。

> 在下面的示例中，myNum 的初始值将导致死循环。If...Then...Else 语句检查此条件，防止出现死循环。

> >      Sub ExitExample()
> >          Dim counter, myNum
> >          counter = 0
> >          myNum = 9
> >          Do Until myNum = 10
> >              myNum = myNum - 1
> >              counter = counter + 1
> >              If myNum < 10 Then Exit Do
> >          Loop
> >          MsgBox "循环重复了 " & counter & " 次。"
> >      End Sub

##### 使用 While...Wend

> While...Wend 语句是为那些熟悉其用法的用户提供的。但是由于 While...Wend 缺少灵活性，所以建议最好使用 Do...Loop 语句。

##### 使用 For...Next

> For...Next 语句用于将语句块运行指定的次数。在循环中使用计数器变量，该变量的值随每一次循环增加或减少。

> 例如，下面的示例将过程 MyProc 重复执行 50 次。For 语句指定计数器变量 x 及其起始值与终止值。Next 语句使计数器变量每次加 1。

> >      Sub DoMyProc50Times()
> >          Dim x
> >          For x = 1 To 50
> >              MyProc
> >          Next
> >      End Sub

> 关键字 Step 用于指定计数器变量每次增加或减少的值。在下面的示例中，计数器变量 j 每次加 2。循环结束后，total 的值为 2、4、6、8 和 10 的总和。

> >      Sub TwosTotal()
> >          Dim j, total
> >          For j = 2 To 10 Step 2
> >              total = total + j
> >          Next
> >          MsgBox "总和为 " & total & "。"
> >      End Sub

> 要使计数器变量递减，可将 Step 设为负值。此时计数器变量的终止值必须小于起始值。在下面的示例中，计数器变量 myNum 每次减 2。循环结束后，total 的值为 16、14、12、10、8、6、4 和 2 的总和。

> >      Sub NewTotal()
> >          Dim myNum, total
> >          For myNum = 16 To 2 Step -2
> >              total = total + myNum
> >          Next
> >          MsgBox "总和为 " & total & "。"
> >      End Sub

> Exit For 语句用于在计数器达到其终止值之前退出 For...Next 语句。因为通常只是在某些特殊情况下（例如在发生错误时）要退出循环，所以可以在 If...Then...Else 语句的 True 语句块中使用 Exit For 语句。如果条件为 False，循环将照常运行。

##### 使用 For Each...Next

> For Each...Next 循环与 For...Next 循环类似。For Each...Next 不是将语句运行指定的次数，而是对于数组中的每个元素或对象集合中的每一项重复一组语句。这在不知道集合中元素的数目时非常有用。

> 在以下示例中，Dictionary 对象的内容用于将文本分别放置在多个文本框中：

> >      <HTML>
> >      <HEAD><TITLE>窗体与元素</TITLE></HEAD>
> >      <SCRIPT LANGUAGE="VBScript">
> >      <!--
> >      Sub cmdChange_OnClick
> >         Dim d                   '创建一个变量
> >         Set d = CreateObject("Scripting.Dictionary")
> >         d.Add "0", "Athens"     '添加键和项目
> >         d.Add "1", "Belgrade"
> >         d.Add "2", "Cairo"

> >         For Each I in d
> >             Document.frmForm.Elements(I).Value = D.Item(I)
> >         Next
> >      End Sub
> >      -->
> >      </SCRIPT>
> >      <BODY>
> >      <CENTER>
> >      <FORM NAME="frmForm"

> >      <Input Type = "Text"><p>
> >      <Input Type = "Text"><p>
> >      <Input Type = "Text"><p>
> >      <Input Type = "Text"><p>
> >      <Input Type = "Button" NAME="cmdChange" VALUE="单击此处"><p>
> >      </FORM>
> >      </CENTER>
> >      </BODY>
> >      </HTML>

© 1997 Microsoft Corporation. All rights reserved. Terms of Use.